alertas de fechas con excel - parte II

En la primer entrada sobre este asunto (link), vimos una de las cientos, o miles, de formas en que podemos solicitarle a Excel que nos "avise" cuando estamos frente a un determinada fecha. Pero un lector del blog necesita otra alternativa, misma que trataremos en la presente entrada.

Veamos la siguiente tabla:

[+/-] Ver el resto / Ocultar

La primer columna hace referencia a la fecha en que un cliente debe abonar el interés de una cuota. La segunda posee la fecha del sistema (=HOY()), siendo que en la tercera, y mediante la función =SI(B2=A2;"ALERTA";""), logramos que Excel nos diga cuando ambas fechas son coincidentes. Noten el recuadro que realicé: las fechas de ambas columnas son iguales. La columna D no entendí bien para que es (jeje, todo no se puede) y en la última tenemos el importe a pagar.

Bueno, mi lector necesita que, al abrir el libro, un formulario le refleje todas las fechas que son idénticas, indicando el importe que el cliente debe abonar. Solucionaremos esto con un UserForm y un ListBox.

Empecemos.

Si queremos "que algo suceda" al abrir el libro....listo, VBA nos soluciona casi todo, dado que el Workbook posee un Sub para ello:

listo, cualquier código (válido) que incluyamos dentro ese procedimiento se ejecutará al abrirse el libro.

Sigamos.

Ahora debo:

1) Llamar a un formulario

2) Revisar las fechas de las columnas A y B

3) Si son coincidentes, darlas de alta en un ListBox.

Un UserForm posee muchas propiedades, métodos y eventos. Utilizaremos un evento en particular: Initialize, que se produce, como imaginarán, cada vez que se "inicializa" el formulario en cuestión. No confundir con "Activate": son parecidos, pero no tanto. "Activate" es cada vez que se "activa" el formulario: si llamo a dicho objeto se activa, pero si luego de esa acción aparece un MsgBox u otro formulario y vuelvo al primero.... se "activa" de nuevo. ¿Se entiende la idea? Solo se "inicializa" una vez, pero puede ser "activado" muchas veces. 

Agregamos un UserForm al proyecto y dentro de el colocamos un ListBox:

Hacemos doble click sobre el formulario y una vez que estamos en su ventana de código elegimos el Sub Initialize, para escribir allí esto:

Private Sub UserForm_Initialize()
Dim Uf As Long 'para determinar la ultima fila de la tabla
Dim X As Long 'para el bucle

'almaceno la ultima fila ocupada de la tabla
Uf = Cells(Cells.Rows.Count, 1).End(xlUp).Row

'ahora recorro con un bucle, desde la segunda fila
'(por el encabezado de la tabla) hasta la última:
For X = 2 To Uf
    'si ambas celdas poseen valor:
    If Cells(X, 1) <> "" And Cells(X, 2) <> "" Then
        'si ambos valores son fechas:
        If IsDate(Cells(X, 1)) And IsDate(Cells(X, 2)) Then
            'y si las fechas son coincidentes:
            If Cells(X, 1) = Cells(X, 2) Then
                lstCuotas.AddItem Cells(X, 1) _
                & " - abona: " & Format(Cells(X, 5), "currency")
            End If
        End If
    End If
Next X
End Sub

Vean que dentro del bucle For... hago una serie de "validaciones": si ambas celdas (de la columna A y B) tienen valores, si esos valores son fechas y, por último, si ambas fechas son iguales cargo el dato en el ListBox, al cual llamé "lstCuotas". Hago una concatenación:

lstCuotas.AddItem Cells(X, 1)  & " - abona: " & Format(Cells(X, 5), "currency")

en donde se aprecia que uno lo que hay en la primer columna con una palabra: abona, para luego juntarlo al valor existente en la quinta columna (importe), al cual le estoy dando el formato de moneda (currency)

El resultado:

todas las fechas del interés que coinciden con la fecha actual del sistema están dentro del ListBox

Nos dirigimos ahora al explorador de proyectos, hacemos doble click sobre "ThisWorkbook" (este libro) y seleccionando el sub Workbook_Open escribimos el siguiente código:

Private Sub Workbook_Open()
    UserForm1.Show
End Sub

O sea: llamamos al formulario, quien en su evento Initialize lanzará el código ya mostrado.

Desconozco cuales serán los planes a futuro o si esa tabla podrá o no ser modificada, pero podríamos tranquilamente prescindir de la segunda columna, haciendo la comparación de fechas directamente desde VBA, de la siguiente forma:

If Cells(X,1) = Date Then

  'codigo del ejemplo

End If

Lo que hice arriba es reemplazar la segunda columna (en donde se muestra la fecha actual del sistema) por la función Date de VBA, que hace exactamente lo mismo.

Espero que el ejemplo les sea de utilidad y puedan adaptarlo. No es difícil: con cambiar el número de columna dentro de Cells(fila, columna) ya se pueden lograr modificaciones "flexibles" que permitirán acomodarlo mejor al trabajo que estén realizando.

Un abrazo - link al archivo