macros: como enviar mails desde Excel (vba)

Un gran amigo "on-line", Johan Moreno, de Colombia, me hizo llegar la inquietud de cómo enviar mails desde Excel. Si bien contaba con algunas líneas de código sobre el particular, decidí retomar mi ejemplo y adaptarlo mejor a las circunstancias. Hace unos minutos termino de remitirle un correo con la solución a Johan... desde Excel y con un archivo adjunto, mismo que transcribo a continuación para ayudar a todos con esta tarea.

Veamos primero las dos formas principales de enviar mails: mediante Outlook o nuestro Web Mail (yahoo, gmail, hotmail, etc, etc) No soy usuario de Outlook en lo absoluto: no confío en los agujeros de seguridad que continuamente aparecen y, por otro lado, teniendo a mi alcance una herramienta tan poderosa (y gratuita) como Gmail, la cual ahora también permite sincronizar los mensaje con la Pc para verlos offline (deben activarlo en "google labs")... no creo que me haga usuario ni hoy ni mañana. Igualmente mas adelante daré una solución para aquellos que "no les queda otra", lo cual generalmente se produce por motivos laborales.

[+/-] Ver el resto / Ocultar

Empecemos: utilizaremos una cuenta de Gmail para enviar correos electrónicos desde Excel. Si sos usuario de algún otro web mail, simplemente reemplazá los parámetros indicados.

Analizando un poco este pequeño proyecto, sería adecuado crear en una hoja o formulario los campos requeridos para que el envío se producza de forma satisfactoria. Hagamos el siguiente diseño:

diseñado en una hoja llamada WebMail, a partir de la primer fila. Sencillo. Omito aquí los detalles referentes de la cuenta a traves de la cual enviaremos los correos (gmail, en este caso), mismos que incorporo dentro del código.

Ya definimos los principales campos, comunes a cualqueir servicio de correo. Abrimos VBA (alt + f11) y antes de escribir el código, debemos referenciar la librería de objetos que nos proporcionará los metodos para hacer factible el envio de mails: Microsoft CDO for Windows 2000 Library (CDO= Colaboration Data Object). Accedemos a esto mediante el menú "Herramientas / Referencias" y del formulario emergente buscamos y seleccionamos la mencionada opcion:

si omitimos este paso... nuestra macro no funcionará. los elementos están ordenados alfabeticamente, por lo tanto nos resultará fácil encontrarlos.

Ahora sí, el código, mismo que se encuentra muy comentado, para facilitar su comprensión:

Function EnviarMails_CDO() As Boolean
    
' Creo la variable de objeto CDO
Dim Email As CDO.Message
Dim Autentificion As Boolean

' ahora doy vida al objeto
Set Email = New CDO.Message

'indicamos los datos del servidor:
Email.Configuration.Fields(cdoSMTPServer) = "smtp.gmail.com"
Email.Configuration.Fields(cdoSendUsingMethod) = 2
'indicamos el nro de puerto. por defecto es el 25, pero gmail usa el 465. hay otro
'(que ahora no recuerdo) pero no me funcionaba... por eso no lo usé mas y lo olvidé
Email.Configuration.Fields.Item _
    ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = CLng(465)
'aqui dejamos en claro si el servidor que usamos requiere o nó autentificación.
'1=requiere, 0=no requiere. Para gmail, entonces, 1
Email.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/" & _
            "configuration/smtpauthenticate") = Abs(1)
'segundos para el tiempo maximo de espera. aconsejo no modificarlo:
Email.Configuration.Fields.Item _
    ("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 30
    
    
'aqui defino como True (verdadera) a la autentificación para el envío de mails.
Autentificacion = True
'ahora configuramos las opciones de login de gmail:
If Autentificacion Then
    'nombre de usuario
    Email.Configuration.Fields.Item _
        ("http://schemas.microsoft.com/cdo/configuration/sendusername") = "tuusuario@gmail.com"
    'contraseña
    Email.Configuration.Fields.Item _
        ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "tucontraseña"
    'si el servidor utiliza SSL (secure socket layer). en gmail: True
   Email.Configuration.Fields.Item _
        ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
End If
    
    'a partir de ahora tomaremos los datos incluidos en el la hoja de excel:
    ' Dirección del Destinatario
    Email.To = Trim([e1].Value)
    
    ' Dirección del remitente
    Email.From = Trim([e2].Value)
    
    ' Asunto del mensaje
    Email.Subject = Trim([e3].Value)
    
    ' Cuerpo del mensaje
    Email.TextBody = Trim([e4].Value)
    
    'Ruta del archivo adjunto
    If [e5].Value <> vbNullString Then
        Email.AddAttachment (Trim([e5].Value))
    End If
    
    'antes de enviar actualizamos los datos:
    Email.Configuration.Fields.Update
    'colocamos un capturador de errores, por las dudas:
    On Error Resume Next
    'enviamos el mail
    Email.Send
    'si el numero de error es 0 (o sea, no existieron errores en el proceso),
    'hago que la función retorne Verdadero
    If Err.Number = 0 Then
       EnviarMails_CDO = True
    Else
      'caso contrario, muestro un MsgBox con la descripcion y nro de error
       MsgBox "Se produjo el siguiente error: " & Err.Description, vbCritical, "Error nro " & Err.Number
    End If
    
    'destruyo el objeto, para liberar los recursos del sistema
    If Not Email Is Nothing Then
        Set Email = Nothing
    End If
    'libero posibles errores
    On Error GoTo 0
End Function

'este sub es el que asignaré al botón de la hoja:

Sub EnviarMail()
    Dim MailExitoso As Boolean
    'llamo a la funcion:
    MailExitoso = EnviarMails_CDO()
    'si me devuelve un resultado Verdadero, todo salió bien:
    If MailExitoso = True Then
        MsgBox "El mail fué enviado satisfactoriamente", vbInformation, "Informe"
    End If
End Sub 

---

Con lo visto hasta el momento podemos enviar mails sin inconvenientes, aunque solo resta decir que es un ejemplo muy básico y mejorable en extremo. Podríamos crear "listas" de destinatarios y evitar así el ingreso manual de cada uno de ellos. O bien abrir un cuadro de diálogo para seleccionar manualmente el archivo que remitiremos adjunto.

Otra opcion muy útil: guardar una determinada hoja (por ejemplo el resumen de venta semanal) como un nuevo libro de excel y enviarla adjunta, sin necesidad de: cerrar excel, abrir el web mail, adjuntar el archivo y enviar, que serían los pasos comunes que debemos realizar.

La automatización puede ser total. Quedo al aguardo de consultas para ampliar el tema.