otra de api's: obtener la resolución de pantalla con una macro

En mi anterior entrada vimos muy someramente que son las API's de Windows, junto con algunos ejemplos (obtener directorio del sistema, saber si el usuario activo está definido como Administrador, abrir y cerrar la lectora de cd). Continuando con ests temática, les dejaré unas líneas de código que hacen lo siguiente: obtener la resolución de pantalla y ajustar el zoom de Excel en función a ella. Si esta resolución no está contemplada en nuestro código, un cartel avisará de ello (siempre hay alguno con monitores "raros"):

[+/-] Ver el resto / Ocultar

¿Para qué saber la resolución de la pantalla? Sencillo: muchas veces diseñaremos formularios, gráficos, autoformas, etc, etc respetando una medida determinada. Si el libro se visualiza en un monitor de 800x600 y nosotros diseñamos en uno de 1920x1200, seguro se verá "mal", fuera de pantalla. Entonces, si captamos esto con una API nos será factible ajustar el zoom de Excel y que nuestro proyecto se vea siempre correctamente.

Vamos al código, el cual se encuentra bien comentado para ayudar en la compresión del mismo:

Option Explicit
'definimos un tipo, que luego será pasado como argumento a la API
Type RECT
   x1 As Long
   y1 As Long
   x2 As Long
   y2 As Long
End Type

'bueno, mis queridas APIS. son un tanto difíciles de comprender, pero extremadamente
'utiles para todo programador.
'para hacerlo mas sencillo: no te olvides nunca que una función siempre devuelve un valor
'y eso hará nuestra api. luego leeremos ese valor para decirle a nuestra macro que ajuste
'el zoom de acuerdo a las circunstancias:
Declare Function GetDesktopWindow Lib "User32" () As Long
Declare Function GetWindowRect Lib "User32" _
      (ByVal hWnd As Long, rectangle As RECT) As Long

Function ObtenerResolucion() As String
'la función en sí. yo mismo creo una función que utilizará las dos apis y concatenaré
'los resultados para crear una salida del tipo "800x600", etc, etc
   Dim R As RECT
   Dim hWnd As Long
   Dim RetVal As Long

   hWnd = GetDesktopWindow()
   RetVal = GetWindowRect(hWnd, R)
   'aquí esta la concatenación
   ObtenerResolucion = (R.x2 - R.x1) & "x" & (R.y2 - R.y1)
End Function
Sub Auto_Open()
'auto_open es un sub que excel lo ejecuta al inicio del libro.
'aqui pondremos nuestro código:
Dim Resultado As String
'averiguo la resolución:
Resultado = Trim(ObtenerResolucion)
'y en base al resultado obtenido, utilizo un simple select case, en el cual
'tomo las distintas pautas a seguir:
Select Case Resultado
    Case "800x600"
        ActiveWindow.Zoom = 90
    Case "1024x768"
        ActiveWindow.Zoom = 110
    Case Else
        MsgBox "La resolución actual de la pantalla es: " & Resultado & vbCrLf _
        & "Contacte a su programador para que ajuste los parámetros, debido a que " _
        & "posiblemente la visualización de la plantilla no sea la correcta", vbInformation, "Atención"
End Select
End Sub

 

Noten el último procedimiento, así de paso aprendemos algo nuevo: se llama Auto_Open(). Esto significa que dicho Sub se ejecutará si o si automáticamente cada vez que abramos el libro.